Image:Buck continuous discontinuous french.png
Un article de Wikipédia, l'encyclopédie libre.
Taille de cet aperçu : 800 × 560 pixels
Image en plus haute résolution (1 500 × 1 050 pixels, taille du fichier : 35 Kio, type MIME : image/png)
| Ce fichier provient de Wikimedia Commons?. Les informations le concernant sont affichées ci-dessous (procédure). |
[edit] Summary
french translation of Buck_continuous_discontinuous.png by Cyril BUTTAY
graph Us=f(Is) of a buck converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain):
# This file is used to plot the domains of continuous and
# discontinuous operation of a buck converter
# graph configuration
set terminal postscript eps enhanced "Times-Roman" 24
set encoding iso_8859_15
unset title
set style line 1 lt 10 lw 3 pt 0 ps 0
set style line 2 lt 3 lw 3 pt 0 ps 0
set border 15 lt 10 lw 4
set mxtics
set mytics
set grid xtics ytics
set ylabel "Tension normalisée"
set xlabel "Courant normalisé"
set format y '%0.2f'
set format x "%0.2f"
set samples 1000
# labels displayed on the graph
set label 1 'discontinue' at 0.02,0.23
set label 2 'conduction continue' at 0.1,0.23
set label 3 "\\alpha=0.1" at 0.24,0.13 right
set label 4 "\\alpha=0.3" at 0.24,0.33 right
set label 5 "\\alpha=0.5" at 0.24,0.53 right
set label 6 "\\alpha=0.7" at 0.24,0.73 right
set label 7 "\\alpha=0.9" at 0.24,0.93 right
# normalized voltage=g(normalized current)
f(x,D) = 1/(2*x/D**2+1)
g(x,D) = f(x,D)<=D?D:f(x,D)
x1(t) = t
#parametric functions for plotting of domain limit
set parametric
my_x(t) = (1-t)/2*t
my_y(t) = t
set output "buck_continuous_discontinuous_french.eps"
# the plot is set as parametric, so each curve is defined by two values: x,y
plot [0:1][0:0.25][0:1] t,g(t,0.1) ls 1 title '', \
t,g(t,0.3) ls 1 title '', \
t,g(t,0.5) ls 1 title '',\
t,g(t,0.7) ls 1 title '',\
t,g(t,0.9) ls 1 title '', \
t,g(t,1) ls 1 title '',\
my_x(t),my_y(t) ls 2 title ''
Then it is converted in png format using the following command (Linux):
convert -density 300 buck_continuous_discontinuous_french.png buck_continuous_discontinuous_french.png
[edit] Licensing
Historique du fichier
Cliquer sur une date et une heure pour voir le fichier tel qu’il était à ce moment-là
| Date et heure | Dimensions | Utilisateur | Commentaire | |
|---|---|---|---|---|
| actuel | 30 juillet 2006 à 13:52 | 1 500×1 050 (35 Kio) | Yves-Laurent | (== Summary == french translation of Buck_continuous_discontinuous.png by Cyril BUTTAY graph Us=f(Is) of a buck converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain): <pre> # This fi) |
| 30 juillet 2006 à 13:48 | 1 500×1 050 (35 Kio) | Yves-Laurent | (== Summary == french translation of Buck_continuous_discontinuous.png by Cyril BUTTAY graph Us=f(Is) of a buck converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain): <pre> # This fi) | |
| 20 juillet 2006 à 20:35 | 1 500×1 050 (68 Kio) | Yves-Laurent | (== Summary == french translation of Buck_continuous_discontinuous.png by Cyril BUTTAY graph Us=f(Is) of a buck converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain): <pre> # This fi) |
Pages contenant l’image
Les pages ci-dessous contiennent cette image :
